﻿;################################################;
;#         Standard Z-80 macro library          #;
;#==============================================#;
;#      Date:      16-Jun-80                    #;
;#      Last Rev:  21-Aug-81                    #;
;################################################;
;
;       alldig macro    test character string for all digits
;
;       alldig  strptr
;
;               strptr is a pointer to the string to be tested;
;               if omitted, then assumed in DE.  Upon return,
;               CY = 0 if string contains only digits.
;
alldig  macro   #strptr
        global  @aldig
        if      "#strptr"<>""
        ld      de,#strptr
        endif
        defb    0cdh            ;;call the subroutine
        defw    @aldig
        endm
;
;       . . . . . . . . . . . . . . . . . . . . . . . . . . . .
;
;       br macro        this macro replaces the standard Z80
;                       jr opcode.
;
;               br may take the following forms:
;                       br      adr
;                       br      cc,adr
;               where  cc is one of z, nz, c, nc, eq, ne,
;                gt, ge, lt, ge
;
br      omacro  #arg1,#arg2
        if      "#arg2"=""
        jr      #arg1           ;; br #arg1
        else
        ?tstc   #arg1
        if      ?cond<4         ;; std Z80 jr instruction
        if      "#arg1"="ne"
        jr      nz,#arg2
        exitm
        endif
        if      "#arg1"="eq"
        jr      z,#arg2
        exitm
        endif
        if      "#arg1"="ge"
        jr      nc,#arg2
        exitm
        endif
        if      "#arg1"="lt"
        jr      c,#arg2
        exitm
        endif
        jr      #arg1,#arg2
        exitm
        endif
        if      ?cond=8         ;; br gt,#arg2
        jr      z,$+4
        jr      nc,#arg2
        exitm
        endif
        if      ?cond=9         ;; br le,#arg2
        jr      c,#arg2
        jr      z,#arg2
        exitm
        endif
        synerr                  ;; syntax error
        endif
        endm
;
;       . . . . . . . . . . . . . . . . . . . . . . . . . . . .
;
;       call macro      this macro replaces the standard Z80
;                       call opcode.
;
;               call may take the following forms:
;                       call    adr
;                       call    (xx)
;                       call    cc,adr
;               where xx is one of hl, ix & iy
;                & cc is one of z, nz, c, nc, pe, po, p, m, eq, ne,
;                gt, ge, lt, ge, v (overflow) & nv (no overflow)
;
call    omacro  #arg1,#arg2
        if      "#arg2"=""
        defb    0cdh
        if      "#arg1"="(hl)"  ;; call (hl)
        global  @calhl
        defw    @calhl
        exitm
        endif
        if      "#arg1"="(ix)"  ;; call (ix)
        global  @calix
        defw    @calix
        exitm
        endif
        if      "#arg1"="(iy)"  ;; call (iy)
        global  @caliy
        defw    @caliy
        exitm
        endif
        defw    #arg1           ;; call #arg1
        else
        ?tstc   #arg1
        if      ?cond<8         ;; std 8080 call instruction
        defb    0c4h|[?cond<<3]
        defw    #arg2
        exitm
        endif
        if      ?cond=8         ;; call gt,#arg2
        jr      z,$+5
        defb    0d4h
        defw    #arg2
        exitm
        endif
        if      ?cond=9         ;; call le,#arg2
        jr      c,$+4
        jr      nz,$+5
        defb    0cdh
        defw    #arg2
        exitm
        endif
        endif
        endm
;
;       . . . . . . . . . . . . . . . . . . . . . . . . . . . .
;
;       cbios macro     call bios routines directly
;
;       cbios   function,param
;
cbios   macro   #funct,#param
        if      "#param"<>""
        ld      bc,#param
        endif
        global  @cbios
        defb    0cdh
        defw    @cbios
        defb    #funct
        endm
;
;       . . . . . . . . . . . . . . . . . . . . . . . . . . . .
;
;       charin macro    console input to a
;
;       charin  addr
;
charin  macro   #dest
        global  @chari
        defb    0cdh
        defw    @chari
        if      "#dest"<>""
        ld      #dest,a
        endif
        endm
;
;
;       . . . . . . . . . . . . . . . . . . . . . . . . . . . .
;
;       chrout macro    console output from a
;
;       chrout  addr
;
chrout  macro   #addr
        global  @charo
        if      "#addr"<>""
        ld      a,#addr
        endif
        defb    0cdh
        defw    @charo
        endm
;
;       . . . . . . . . . . . . . . . . . . . . . . . . . . . .
;
;       charst macro    check console status
;
;                       return true (ff) if char ready, false (0) if not
;
charst  macro
        global  @chars
        defb    0cdh
        defw    @chars
        endm


clra    macro           ;; A := 0
        xor     a,a
        endm


clrcf   macro           ;; CY := 0
        or      a,a
        endm
;
;       . . . . . . . . . . . . . . . . . . . . . . . . . . . .
;
;       decin macro     convert a number in memory from ascii to binary
;
;       decin   addr
;
;               addr points to memory location of start of no, if
;               arg omitted pointer assumed loaded to DE
;               Scans past leading blanks and tabs.  Conversion
;               stops when char less than zero is found.
;               macro returns with DE pointing to character which
;               stopped scan.  16 bit binary result is left in HL,
;               (maximum 65,767).  Least significant 8 bits of number
;               in reg A.
;
decin   macro   #addr
        global  @decin
        if      "#addr"<>""
        ld      de,#addr
        endif
        defb    0cdh            ;;call the subroutine
        defw    @decin
        ld      a,l             ;;least significant half of no to A
        endm
;
;       . . . . . . . . . . . . . . . . . . . . . . . . . . . .
;
;       decout macro    Convert a positive integer to decimal and output
;                       to the console with field width >= width.
;
;       decout  arg,width
;
;               if arg omitted, number assumed to be in HL, else loaded to HL
;               Number is right-justified and the field is blank padded.
;               Width defaults to 1 if omitted.  Leading zeros suppressed.
;               Maximum number is 65,767.
;
decout  macro   #arg,#width
        global  @decot
        if      "#arg"<>""
        ld      hl,#arg
        endif
        if      "#width"<>""
        ld      a,#width
        else
        ld      a,1             ;;width defaults to 1
        endif
        defb    0cdh            ;;call the subroutine
        defw    @decot
        endm
;
;       . . . . . . . . . . . . . . . . . . . . . . . . . . . .
;
;       divide macro    unsigned 16 bit integer division
;
;       divide  int1,int2
;
;       entry:  HL = dividend, DE = divisor
;       exit:   HL = quotient, DE = remainder
;               CY = set if error, reset if ok
;
divide  macro   #int1,#int2
        if      "#int1"<>""
        ld      hl,#int1
        endif
        if      "#int2"<>""
        ld      de,#int2
        endif
        global  @div16
        defb    0cdh
        defw    @div16
        endm
;
;       . . . . . . . . . . . . . . . . . . . . . . . . . . . .
;
;       dload macro     double precision indexed load hl
;
;               load (addr + indx) to hl
;
dload   macro   #addr,#indx
        if      "#indx"=""
        ld      hl,(#addr)
        else
        ld      hl,(#indx)
        ld      de,#addr
        add     hl,de
        ld      e,(hl)
        inc     hl
        ld      d,(hl)
        ex      de,hl
        endif
        endm
;
;       . . . . . . . . . . . . . . . . . . . . . . . . . . . .
;
;       dstore macro    double precision indexed store hl
;
;               store (hl) in (addr + indx)
;
dstore  macro   #addr,#indx
        if      "#indx"=""
        ld      (#addr),hl
        else
        save    hl
        ld      hl,(#indx)
        ex      de,hl
        ld      hl,#addr
        add     hl,de
        restor  de
        mov     (hl),e
        inc     hl
        mov     (hl),d
        endif
        endm
;
;       . . . . . . . . . . . . . . . . . . . . . . . . . . . .
;
;       dsub macro      double precision subtract
;
dsub    macro   #reg0,#reg1
        or      a,a
        sbc     #reg0,#reg1
        endm
;
;       . . . . . . . . . . . . . . . . . . . . . . . . . . .
;
;       filfcb  macro   fill in the id fields of fcb
;
;       filfcb  fcb,idstring
;
;               idstring contains file name and type  (filnam.typ)
;               carry set if error  (name too long)
;
filfcb  macro   #fcb,#idstr
        global  @flfcb
        if      "#idstr"<>""
        ld      de,#idstr
        endif
        if      "#fcb"<>""
        ld      hl,#fcb
        endif
        defb    0cdh
        defw    @flfcb
        ex      de,hl
        endm
;
;       . . . . . . . . . . . . . . . . . . . . . . . . . . . .
;
;       fill macro - fill a block of memory with a constant
;
;       fill    start,stop,constant
;
;               constant omitted, fill with 0
;               end omitted, fill one byte
;
fill    macro   #start,#stop,#const
        ld      hl,#start       ;;load start addr
        if      "#stop"=""
        if      "#const"=""
        ld      (hl),0          ;;store a zero
        else
        ld      (hl),#const     ;;store single byte
        endif
        else
        ld      bc,#stop-#start+1 ;;load block length
        if      "#const"<>""
        ld      e,#const        ;;load const if not null
        else
        ld      e,0
        endif
        global  @fill
        defb    0cdh
        defw    @fill
        endif
        endm
;
;       . . . . . . . . . . . . . . . . . . . . . . . . . . . .
;
;       hexin macro     convert a number in memory from hex to binary
;
;                       if no argument macro assumes addr of hex string in DE
;                       answer left in HL with least significant 8 bits in A
;                       carry set on error. conversion stops when zero is
;                       found in hex string.
;
hexin   macro   #addr
        global  @hexin
        if      "#addr"<>""
        ld      de,#addr        ;;load buffer addr
        else
        ex      de,hl
        endif
        defb    0cdh
        defw    @hexin
        ld      a,l             ;;least significant 8 bits to a
        endm
;
;       . . . . . . . . . . . . . . . . . . . . . . . . . . . .
;
;       hexout macro    convert binary no and output to console
;
;       hexout  addr
;
;               number assumed in A if no argument
;
hexout  macro   #addr
        global  @hxprn
        if      "#addr"<>""
        ld      a,#addr
        endif
        defb    0cdh
        defw    @hxprn
        endm
;
;       . . . . . . . . . . . . . . . . . . . . . . . . . . . .
;
;       index macro     index an address pointer by a constant
;
;       index   pointer,incr
;
index   macro   #pointer,#incr
        ld      hl,(#pointer)
        ld      de,#incr
        add     hl,de           ;;double add
        ld      (#pointer),hl
        endm
;
;       . . . . . . . . . . . . . . . . . . . . . . . . . . . .
;
;       input macro     input character string from console
;
;       input   addr,buflen
;
;               addr    start of text buffer
;               buflen  length of buffer  (default is 127)
;
;       carry set if null entry
;
input   macro   #addr,#buflen
        global  @input
        if      "#addr"<>""
        ld      de,#addr        ;;set buffer address
        endif
        if      "#buflen"<>""
        ld      a,#buflen       ;;set buffer length
        else
        ld      a,127           ;;set buffer default maximum
        endif
        defb    0cdh
        defw    @input
        endm
;
;       . . . . . . . . . . . . . . . . . . . . . . . . . . . .
;
;       jp macro        this macro replaces the standard Z80
;                       jp opcode.
;
;               jp may take the following forms:
;                       jp      adr
;                       jp      (xx)
;                       jp      cc,adr
;               where xx is one of hl, ix & iy
;                & cc is one of z, nz, c, nc, pe, po, p, m, eq, ne,
;                gt, ge, lt, ge, v (overflow) & nv (no overflow)
;
jp      omacro  #arg1,#arg2
        if      "#arg2"=""
        if      "#arg1"="(hl)"
        defb    0e9h            ;; jp (hl)
        exitm
        endif
        if      "#arg1"="(ix)"
        defb    0ddh,0e9h       ;; jp (ix)
        exitm
        endif
        if      "#arg1"="(iy)"
        defb    0fdh,0e9h       ;; jp (iy)
        exitm
        endif
        defb    0c3h            ;; jp #arg1
        defw    #arg1
        else
        ?tstc   #arg1
        if      ?cond<8         ;; std 8080 jp instruction
        defb    0c2h|[?cond<<3]
        defw    #arg2
        exitm
        endif
        if      ?cond=8         ;; jp   gt,#arg2
        jr      z,$+5
        defb    0d2h
        defw    #arg2
        exitm
        endif
        if      ?cond=9         ;; jp le,#arg2
        defb    0dah
        defw    #arg2
        defb    0cah
        defw    #arg2
        exitm
        endif
        endif
        endm
;
;       . . . . . . . . . . . . . . . . . . . . . . . . . . . .
;
;       move macro      move a block from source to dest
;
;       move    source,dest,count
;
;               source to hl    macro assumes registers already
;               dest to de      loaded if arg omitted
;               count to bc
;
move    macro   #source,#dest,#count
        if      "#source"<>""
        ld      hl,#source
        endif
        if      "#dest"<>""
        ld      de,#dest
        endif
        if      "#count"<>""
        ld      bc,#count
        endif
        ldir                    ;;easy on Z80
        endm
;
;       . . . . . . . . . . . . . . . . . . . . . . . . . . . .
;
;       mulply macro    multiply 16 bit integers
;
;       entry:  HL = multiplicand, DE = multiplier
;       exit:   HL = product
;
mulply  macro   #int1,#int2
        if      "#int1"<>""
        ld      hl,#int1
        endif
        if      "#int2"<>""
        ex      de,hl
        ld      hl,#int2
        endif
        global  @mul16
        defb    0cdh
        defw    @mul16
        endm
;
;       . . . . . . . . . . . . . . . . . . . . . . . . . . . .
;
;       print macro     print a string on console
;
;       print                           (carriage return, line feed)
;       print   'literal'
;       print   'literal',cr,lf,'second literal'
;
;               literals must be in single quotes  'lit'
;
print   macro   #0,#1,#2,#3,#4,#5,#6,#7,#8,#9
        if      "#0#1#2#3#4#5#6#7#8#9"=""
        global  @crlf
        call    @crlf
        else
        global  @prlit
        call    @prlit
        irp     #c,#0,#1,#2,#3,#4,#5,#6,#7,#8,#9
        if      "#c"=""
        exitm
        endif
        defb    #c
        endm
        defb    0               ;; End Of String character
        endif
        endm
;
;       . . . . . . . . . . . . . . . . . . . . . . . . . . . .
;
;       restor macro    restore registers  (inverse of save)
;
;       restor  r1,r2,r3,r4,r5,r6
;
;               r1-r6 may be BC,DE,HL,IX,IY or AF  restored in order
;               specified.  If regs omitted restore BC,DE and HL.
;
restor  macro   #r1,#r2,#r3,#r4,#r5,#r6
        if      "#r1#r2#r3#r4#r5#r6"<>""
        irp     #x,#r1,#r2,#r3,#r4,#r5,#r6
        if      "#x"=""
        exitm
        endif
        pop     #x
        endm
        else
        irp     #x,bc,de,hl
        pop     #x
        endm
        endif
        endm
;
;       . . . . . . . . . . . . . . . . . . . . . . . . . . . .
;
;       ret macro       this macro replaces the standard Z80
;                       ret opcode.
;
;               ret may take the following forms:
;                       ret
;                       ret     cc
;               where cc is one of z, nz, c, nc, pe, po, p, m, eq, ne,
;                gt, ge, lt, ge, v (overflow) & nv (no overflow)
;
ret     omacro  #arg
        if      "#arg"=""       ;; ret
        defb    0c9h
        else
        ?tstc   #arg
        if      ?cond<8         ;; std 8080 ret instruction
        defb    0c0h|[?cond<<3]
        exitm
        endif
        if      ?cond=8         ;; ret gt
        jr      z,$+3
        defb    0d0h
        exitm
        endif
        if      ?cond=9         ;; ret le
        defb    0d8h
        defb    0c8h
        exitm
        endif
        endif
        endm
;
;       . . . . . . . . . . . . . . . . . . . . . . . . . . . .
;
;       save macro      save specified registers
;
;       save    r1,r2,r3,r4,r5,r6
;
;               r1-r6 may be BC, DE, HL, AF, IX or IY saved
;               in order specified.  If regs are omitted save
;               HL, DE, and BC.
;
save    macro   #r1,#r2,#r3,#r4,#r5,#r6
        if      "#r1#r2#r3#r4#r5#r6"<>""
        irp     #x,#r1,#r2,#r3,#r4,#r5,#r6
        if      "#x"=""
        exitm
        endif
        push    #x
        endm
        else
        irp     #x,hl,de,bc
        push    #x
        endm
        endif
        endm
;
;       . . . . . . . . . . . . . . . . . . . . . . . . . . . .
;
;       skipbl macro    skip leading blanks and tabs
;
;       skipbl  str
;
;               If str is not present, assumed to be in DE.
;               Upon return, DE points to first non-whitespace
;               character.
;
skipbl  macro   #str
        if      "#str"<>""
        ld      de,#str
        endif
        global  @skipb
        defb    0cdh
        defw    @skipb
        endm
;
;       . . . . . . . . . . . . . . . . . . . . . . . . . . . .
;
;       system macro    execute bdos primitives
;
;       system  func,param
;
;               see cp/m interface guide for detailed information on the
;               bdos primitives
;
;       system  read,fcb        (typical macro call)
;
system  macro   #func,#param
        if      "#param"<>""
        ld      de,#param
        endif
        if      "#func"=""
        synerr
        else
        global  @systm
        defb    0cdh
        defw    @systm
        defb    #func
        endif
        endm
;
;       . . . . . . . . . . . . . . . . . . . . . . . . . . . .
;
;       tbr macro       test reg(s) and branch on condition
;
tbr     omacro  #reg,#cond,#addr
        tst     #reg
        br      #cond,#addr
        endm
;
;       . . . . . . . . . . . . . . . . . . . . . . . . . . . .
;
;       tcall macro     test reg(s) and call on condition
;
tcall   omacro  #reg,#cond,#addr
        tst     #reg
        call    #cond,#addr
        endm
;
;       . . . . . . . . . . . . . . . . . . . . . . . . . . . .
;
;       tjp macro       test reg(s) and jump on condition
;
tjp     omacro  #reg,#cond,#addr
        tst     #reg
        jp      #cond,#addr
        endm
;
;       . . . . . . . . . . . . . . . . . . . . . . . . . . . .
;
;       tret macro      test reg(s) and return on condition
;
tret    macro   #reg,#cond
        tst     #reg
        ret     #cond
        endm
;
;       . . . . . . . . . . . . . . . . . . . . . . . . . . . .
;
;
;       tst macro       test register(s) for 0, set flags
;
tst     macro   #r
        ?tstr   #r
        if      ["#r"=""] or [?reg=1] or [?reg=13]
        or      a,a
        else
        if      ?reg<13
        ld      a,#r
        if      ?reg<11         ;; no need to set flags for I & R
        or      a,a
        endif
        else
        if      ?reg<17
        ld      a,#r(1,1)
        or      a,#r(2)
        else
        push    #r
        pop     hl
        ld      a,l
        or      a,h
        endif
        endif
        endif
        endm
;
;       . . . . . . . . . . . . . . . . . . . . . . . . . . . .
;
;
;       tstz80 macro    test if CPU is a Z-80, print error message
;                       and return to CP/M CCP if not
;
tstz80  macro
        global  bdos
        ld      a,70h
        add     a,a             ;; cause overflow on Z-80, odd parity on 8080
        jp      pe,t2#sym       ;; if 8080 then
        ld      de,t0#sym
        ld      c,PRNBUF
        jp      bdos            ;;    print error msg, return to CCP
        ;
t0#sym: defb    'Z-80 only$'
        ;
t2#sym  equ     $
        endm








;################################################;
;#                                              #;
;#         standard macros for MP/M             #;
;#                                              #;
;################################################;
;
;       macro bldapb:   build assign (console) parameter block
;
bldapb  macro   #name,#con,#bool
        defb    #con
        bldnam  #name
        if      "#bool" = ""
        defb    0ffh            ;; default is true (match PD console)
        else
        defb    #bool
        endif
        endm
;
;       . . . . . . . . . . . . . . . . . . . . . . . . . . . .
;
;       macro bldpd:    build process descriptor
;
bldpd   macro   #link,#prior,#start,#name,#cons,#dma,#stksz
        if      "#link" = ""
        defw    0               ;; null link
        else
        defw    #link           ;; link to next PD
        endif
        defb    0               ;; status (set by system)
        if      "#prior" = ""
        defb    200             ;; default priority is 200
        else
        defb    #prior
        endif
        defw    l0#sym          ;; initial stack pointer setting
        bldnam  #name           ;; process name
        defb    #cons           ;; console
        defb    0ffh            ;; memory segment
        defs    2               ;; B (set by system)
        defs    2               ;; thread (set by system)
        defw    #dma            ;; default dma adr
        defs    1               ;; disk select (set by system)
        defs    2               ;; dcnt (set by system)
        defs    1               ;; searchl (set by system)
        defs    2               ;; searcha (set by system)
        defs    2               ;; drives active (set by system)
        defs    20              ;; register save area (used by system)
        defs    2               ;; scratch (system)
        if      "#stksz" = ""
?stkzs  defv    24              ;; default stack size is 24 levels
        else
?stksz  defv    #stksz
        endif
        rept    ?stksz-1
        defw    0c7c7h          ;; fill stack with 0c7c7h to see what's used
        endm
l0#sym: defw    #start          ;; process start address
        endm
;
;       . . . . . . . . . . . . . . . . . . . . . . . . . . . .
;
;       macro bldque:   build queue
;
;       builds circular queue if message length (#mlen) <= 2,
;       linked queue if message length > 2.
;
bldque  macro   #name,#mcnt,#mlen
        defs    2               ;; link field (set by system)
        bldnam  #name           ;; build name field
        defw    #mlen           ;; message length
        defw    #mcnt           ;; message count
        defs    2               ;; DQ process head (set by system)
        defs    2               ;; NQ process head (set by system)
        if      #mlen <= 2      ;; build circular queue
        defs    2               ;; msg in (set by system)
        defs    2               ;; msg out (set by system)
        defs    2               ;; msg count (set by system)
        defs    #mlen*#mcnt     ;; buffer
        else                    ;; build linked queue
        defs    2               ;; message head (set by system)
        defs    2               ;; message tail (set by system)
        defs    2               ;; buffer head (set by system)
        defs    #mcnt*[#mlen+2] ;; buffer
        endif
        endm
;
;       . . . . . . . . . . . . . . . . . . . . . . . . . . . .
;
;       macro bldqcb:   build user queue control block
;
bldqcb  macro   #msgbf,#mlen,#name
        defs    2               ;; pointer to queue (set by system)
        defw    #msgbf          ;; pointer message buffer
        bldnam  #name           ;; build name field
#msgbf: defs    #mlen           ;; start of message buffer
        endm




;################################################;
;#                                              #;
;#              Utility Macros                  #;
;#                                              #;
;################################################;


synerr  macro
**** Syntax error
        endm


;
;       ?tstr macro     utility macro to return register type
;                       value returned in ?reg as below
;
;       Register(s)     ?reg
;       Illegal         0
;       A               1
;       B               2
;       C               3
;       D               4
;       E               5
;       H               6
;       L               7
;       (HL)            8
;       (IX)            9
;       (IY)            10
;       I               11
;       R               12
;       AF              13
;       BC              14
;       DE              15
;       HL              16
;       IX              17
;       IY              18
;
?tstr   macro   #r
?reg    defv    0
?cnt    defv    1
        irp     #x,a,b,c,d,e,h,l,(hl),(ix),(iy),i,r,af,bc,de,hl,ix,iy
        if      "#r"="#x"
?reg    defv    ?cnt
        exitm
        endif
?cnt    defv    ?cnt+1
        endm
        endm
;
;
;       condition(s)    ?cond
;       UNKNOWN         -1
;       NZ,NE           0
;       Z,EQ            1
;       NC,GE           2
;       C,LT            3
;       PO,NV           4
;       PE,V            5
;       P               6
;       M               7
;       GT              8
;       LE              9
;
?tstc   macro   #c
?cond   defv    -1
?cnt    defv    -1
        irp     #x,nz,z,nc,c,po,pe,p,m,gt,le
?cnt    defv    ?cnt+1
        if      "#c"="#x"
?cond   defv    ?cnt
        exitm
        endif
        endm
        if      ?cond<>-1
        exitm
        endif
?cnt    defv    -1
        irp     #x,ne,eq,ge,lt,nv,v
?cnt    defv    ?cnt+1
        if      "#c"="#x"
?cond   defv    ?cnt
        exitm
        endif
        endm
        endm
;
;       . . . . . . . . . . . . . . . . . . . . . . . . . . . .
;
;       macro bldnam:   build name field for MP/M structures
;
bldnam  macro   #name
?cnt    defv    0
        irpc    #char,#name
        if      ["#char" = ""] or [?cnt > 8]
        exitm
        endif
        defb    '#char'
?cnt    defv    ?cnt + 1
        endm
        if      ?cnt < 8
        rept    8 - ?cnt
        defb    ' '
        endm
        endif
        endm